po ile chodza chipy do przrobki Playstation



Masz problem? Zapytaj na forum elektroda.pl z bramką pl.misc.elektronika!

Poprzedni Następny
Wiadomoœć
spis treści
From: "GamBit" <gambit_at_nospam_promail.pl>
Subject: po ile chodza chipy do przrobki Playstation
Date: Sat, 14 Aug 1999 22:45:55 +0200


jak w temacie




Poprzedni Następny
Wiadomoœć
spis treści
From: "Andy" <anok_at_nospam_ceti.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 01:28:49 +0200


GamBit napisał(a) w wiadomości: <37b5d8e0_at_nospam_news.vogel.pl>...
jak w temacie


Ja mam za 20 pln.


Po ile bys chcial ?

pzdr
--
Andrzej
anok_at_nospam_ceti.com.pl
anok_at_nospam_lupus.elektro.agh.edu.pl
KRAKOW




Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 02:59:11 GMT



Andy napisał(a) w wiadomości: <7p7idp$nk6$1_at_nospam_druid.ceti.com.pl>...
GamBit napisał(a) w wiadomości: <37b5d8e0_at_nospam_news.vogel.pl>...
jak w temacie


Ja mam za 20 pln.


Po ile bys chcial ?


hehe, a moze chcesz zrodlo na atmelka 1051 czy 2051 ? he ?

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 03:17:00 GMT


A zreszta macie lamerio - cieszcie sie. To do modelu 7502 na 1051 :-) I tak
lamki nie macie programatorow to g.... wam z tego przyjdzie. A na dodatek
jak nie znacie assemblera to nie dojdziecie, ktory pin gdzie podlaczyc :-)

Juliusz
----------------------------------------------------------------------------
-----------------

; PSX
; Autor Juliusz Model 7502 ma zegar 4,43
NAME SONY_PLAY_STATION_REV_1051 final2

; *******************************************************************
; * DEFINICJE ADRESOW SPRZETOWYCH ORAZ ZMIENNYCH sony *
; * uklad lutowany na kabelkach ! *
; * *
; * 23.09.1997 v 1.2.1051 *
; * *
; * 16667 cykli maszynowych aby doliczyc do 50 ms. *
; * kwarc 4,43 MHz *
; *******************************************************************

; ---------------------------------------------------------------------
; | OPIS SYGNALOW WE-WY P1: |
; | P1.0 - |
; | P1.1 - |
; | P1.2 - |
; | P1.3 - |
; | P1.4 - led test |
; | P1.5 - |
; | P1.6 - |
; | P1.7 - |
; ---------------------------------------------------------------------

;NC equ P1.0
;NC equ P1.1
;NC equ P1.2
;NC equ P1.3
LED equ P1.4
;NC equ P1.5
;NC equ P1.6
;NC equ P1.7

; ---------------------------------------------------------------------
; | OPIS SYGNALOW WE-WY P3: |
; | P3.0 - NC |
; | P3.1 - TxD Dane oszukujace konsole |
; | P3.2 - NC |
; | P3.3 - NC |
; | P3.4 - blokowanie komparatora |
; | P3.5 - NC |
; | P3.6 - NC |
; | P3.7 - NC |
; ---------------------------------------------------------------------

;NC equ P3.0
DANE equ P3.1
;NC equ P3.2
;NC equ P3.3
BLOK equ P3.4
;NC equ P3.5
;NC equ P3.6
CON_1 equ P3.7



; ******************************************************************
; OBSZAR POCZATKOWY KODU PROGRAMU

; ******************************************************************
; Tutaj definiuje adresy systemowe i rejestry SFR

ORG 00H ;START
AJMP START

ORG 0BH ;PUNKT_1_SRV T0
LJMP PUNKT_1_SRV


START: clr EA
IE_SetUp equ 00000000B ; 1=on
; | ||||^ przerwania z INT0
; | |||^ przerwania z T0
; | ||^ przerwania od INT1
; | |^ przerwania od T1
; | ^ przerwania z SIO
; |
; ^ wszystkie przerwania

mov IE,#IE_SetUp


IP_SetUp equ 00000000B
; ||||^ priorytet przerwania z INT0
; |||^ priorytet przerwania z T0
; ||^ priorytet przerwania od INT1
; |^ priorytet przerwania od T1
; ^ priorytet przerwania z SIO
;

mov IP,#IP_SetUp


TMOD_SetUp equ 00010001B
; |||||||^ tryb T0 0,1,2,3
; ||||||^ tryb T0
; |||||^ 0-czasomierz 1-licznik
; ||||^ 1-bramkowanie /INT0
; |||^ tryb T1 0,1,2,3
; ||^ tryb T1
; |^ 0-liczenie wlasnych cykli masz., 1-impulsy zewnetrzne
; ^ 1-bramkowanie /INT1

mov TMOD,#TMOD_SetUp


TCON_SetUp equ 00000000B
; |||||||^ 0-od LOW 1-od HIGH na INT0
; ||||||^
; |||||^
; ||||^
; |||^ 0-stop 1-praca licznika T0
; ||^
; |^ 0-stop 1-praca licznika T1
; ^
mov TCON,#TCON_SetUp

;SCON_SetUp equ 11110000B
; |||||||^ - znacznik odebrania znaku RI
; ||||||^ - znacznik zakonczenia wysylania znaku TI
; |||||^ - dziewiaty znak odbierany RB8
; ||||^ - dziewiaty znak wysylany TB8
; |||^ - uaktywnienie odbiornika REN
; ||^ - multiproces
; |^ - tryb 3 seriala
; ^ - tryb 3 seriala
; mov SCON,#SCON_SetUp

; ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
; ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
;
; PROCEDURY POCZATKOWE PO STARCIE.
;----------------------------------
;wywalone
;5) generowac oszukancze kody 12 bajtow
;6) powtarzac do upadlego punkt 5 i kurwa to tyle !!!!!!!!!!


clr LED
clr CON_1
clr BLOK
clr DANE
mov IE,#10000010B ;wlaczam przerwania T0 + wszystkie

; ******************************************
; * Zaczynamy emulacje seriala *
; ******************************************
; TIMER T1 bedzie liczyl 4 ms
; R0 ilosc okrazen T0 zalezna od potrzeb
; R1 gorny adres pierwszego bajtu do wyslania
; R2 ustala ilosc bajtow do wyslania
; R3 ustala ilosc rotacji bajtu przez carry


TL0_DEF equ 03AH ; 0CBH dla 4MHz
TH0_DEF equ 0FAH ; 0FAH bez zmian

mov 028H,#000H ; end
mov 029H,#000H
mov 02AH,#002H
mov 02BH,#0FAH
mov 02CH,#05DH
mov 02DH,#04BH
mov 02EH,#0C9H
mov 02FH,#059H ; SCEE
mov 030H,#000H
mov 031H,#000H
mov 032H,#002H
mov 033H,#0DAH
mov 034H,#05DH
mov 035H,#04BH
mov 036H,#0C9H
mov 037H,#059H ; SCEE
mov 038H,#000H
mov 039H,#000H
mov 03AH,#002H
mov 03BH,#0EAH
mov 03CH,#05DH
mov 03DH,#04BH
mov 03EH,#0C9H
mov 03FH,#059H ; SCEE

mov R1,#03FH ; gorny adres pierwszego bajtu do nadania
mov R2,#018H ; 22 bajty + 1
mov R3,#008H ; ilosc rotacji + 1
mov TH0,#000H ;niby koryguje pierwsze 4 ms
mov TL0,#001H
mov TCON,#00010000B ;start T0

ALA: mov A,R2
jnz ALA
cpl LED
mov TCON,#00000000B ; stop timera T0
clr DANE
mov R2,#018H ; ustawiam 22 bajty do wyslania
mov R1,#03FH ; adres pierwszego bajtu do wyslania
mov TH0,#TH0_DEF
mov TL0,#TL0_DEF
mov TCON,#00010000B ;start T0
ljmp ALA


PUNKT_1_SRV:
push ACC
push PSW
mov TH0,#TH0_DEF ; timer na 4ms
mov TL0,#TL0_DEF ; jw.
djnz R3,rotate ;odejmij 1 i jump if not 0
mov A,_at_nospam_R1 ;koncowka bajtu aby nie opuszczal 4ms
mov C,ACC.0
rrc A
mov DANE,C
mov _at_nospam_R1,A
mov R3,#008H ;przygotowac nowa rotacje ustaw R1 do liczenia od pocz.
dec R1
dec R2
pop PSW
pop ACC
reti

rotate: mov A,_at_nospam_R1 ; zaladuj bajt danych do akumulatora
mov C,ACC.0 ;korygowanie nieustalonego bitu carry !!!
rrc A ; przekrec go przez carry
mov DANE,C ;wyslij bit
mov _at_nospam_R1,A ; zapisz przekrecony w jego miejsce
pop PSW
pop ACC
reti

end


Poprzedni Następny
Wiadomoœć
spis treści
From: "NameNo" <nameno_at_nospam_free.com.pl>
Subject: Odp: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 05:17:05 GMT


A myślałem że Juliusz nie zajmuje się Hackiem. Tu projekty na FPGA a tu
takie małe na boku.
NameNo
P.S. Nie bądź taki pewny.

Użytkownik Juliusz <juliusz_at_nospam_multi-ip.com.pl> w wiadomości do grup
dyskusyjnych napisał:MoLt3.20974$X3.318527_at_nospam_news.tpnet.pl...
A zreszta macie lamerio - cieszcie sie. To do modelu 7502 na 1051 :-) I
tak
lamki nie macie programatorow to g.... wam z tego przyjdzie. A na dodatek
jak nie znacie assemblera to nie dojdziecie, ktory pin gdzie podlaczyc :-)

Juliusz
--------------------------------------------------------------------------
--
> -----------------
>
> ; PSX
> ; Autor Juliusz Model 7502 ma zegar 4,43
> NAME SONY_PLAY_STATION_REV_1051_final_2
>
> ; *********************************************************************
> ; * DEFINICJE ADRESOW SPRZETOWYCH ORAZ ZMIENNYCH sony *
> ; * uklad lutowany na kabelkach ! *
> ; * *
> ; * 23.09.1997 v 1.2.1051 *
> ; * *
> ; * 16667 cykli maszynowych aby doliczyc do 50 ms. *
> ; * kwarc 4,43 MHz *
> ; *********************************************************************
>
> ; ---------------------------------------------------------------------
> ; | OPIS SYGNALOW WE-WY P1: |
> ; | P1.0 - |
> ; | P1.1 - |
> ; | P1.2 - |
> ; | P1.3 - |
> ; | P1.4 - led test |
> ; | P1.5 - |
> ; | P1.6 - |
> ; | P1.7 - |
> ; ---------------------------------------------------------------------
>
> ;NC equ P1.0
> ;NC equ P1.1
> ;NC equ P1.2
> ;NC equ P1.3
> LED equ P1.4
> ;NC equ P1.5
> ;NC equ P1.6
> ;NC equ P1.7
>
> ; ---------------------------------------------------------------------
> ; | OPIS SYGNALOW WE-WY P3: |
> ; | P3.0 - NC |
> ; | P3.1 - TxD Dane oszukujace konsole |
> ; | P3.2 - NC |
> ; | P3.3 - NC |
> ; | P3.4 - blokowanie komparatora |
> ; | P3.5 - NC |
> ; | P3.6 - NC |
> ; | P3.7 - NC |
> ; ---------------------------------------------------------------------
>
> ;NC equ P3.0
> DANE equ P3.1
> ;NC equ P3.2
> ;NC equ P3.3
> BLOK equ P3.4
> ;NC equ P3.5
> ;NC equ P3.6
> CON_1 equ P3.7
>
>
>
> ; ********************************************************************
> ; OBSZAR POCZATKOWY KODU PROGRAMU
>
> ; ********************************************************************
> ; Tutaj definiuje adresy systemowe i rejestry SFR
>
> ORG 00H ;START
> AJMP START
>
> ORG 0BH ;PUNKT_1_SRV T0
> LJMP PUNKT_1_SRV
>
>
> START: clr EA
> IE_SetUp equ 00000000B ; 1=on
> ; | ||||^ przerwania z INT0
> ; | |||^ przerwania z T0
> ; | ||^ przerwania od INT1
> ; | |^ przerwania od T1
> ; | ^ przerwania z SIO
> ; |
> ; ^ wszystkie przerwania
>
> mov IE,#IE_SetUp
>
>
> IP_SetUp equ 00000000B
> ; ||||^ priorytet przerwania z INT0
> ; |||^ priorytet przerwania z T0
> ; ||^ priorytet przerwania od INT1
> ; |^ priorytet przerwania od T1
> ; ^ priorytet przerwania z SIO
> ;
>
> mov IP,#IP_SetUp
>
>
> TMOD_SetUp equ 00010001B
> ; |||||||^ tryb T0 0,1,2,3
> ; ||||||^ tryb T0
> ; |||||^ 0-czasomierz 1-licznik
> ; ||||^ 1-bramkowanie /INT0
> ; |||^ tryb T1 0,1,2,3
> ; ||^ tryb T1
> ; |^ 0-liczenie wlasnych cykli masz., 1-impulsy zewnetrzne
> ; ^ 1-bramkowanie /INT1
>
> mov TMOD,#TMOD_SetUp
>
>
> TCON_SetUp equ 00000000B
> ; |||||||^ 0-od LOW 1-od HIGH na INT0
> ; ||||||^
> ; |||||^
> ; ||||^
> ; |||^ 0-stop 1-praca licznika T0
> ; ||^
> ; |^ 0-stop 1-praca licznika T1
> ; ^
> mov TCON,#TCON_SetUp
>
> ;SCON_SetUp equ 11110000B
> ; |||||||^ - znacznik odebrania znaku RI
> ; ||||||^ - znacznik zakonczenia wysylania znaku TI
> ; |||||^ - dziewiaty znak odbierany RB8
> ; ||||^ - dziewiaty znak wysylany TB8
> ; |||^ - uaktywnienie odbiornika REN
> ; ||^ - multiproces
> ; |^ - tryb 3 seriala
> ; ^ - tryb 3 seriala
> ; mov SCON,#SCON_SetUp
>
> ; ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
> ; ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
> ;
> ; PROCEDURY POCZATKOWE PO STARCIE.
> ;----------------------------------
> ;wywalone
> ;5) generowac oszukancze kody 12 bajtow
> ;6) powtarzac do upadlego punkt 5 i kurwa to tyle !!!!!!!!!!
>
>
> clr LED
> clr CON_1
> clr BLOK
> clr DANE
> mov IE,#10000010B ;wlaczam przerwania T0 + wszystkie
>
> ; ********************************************
> ; * Zaczynamy emulacje seriala *
> ; ********************************************
> ; TIMER T1 bedzie liczyl 4 ms
> ; R0 ilosc okrazen T0 zalezna od potrzeb
> ; R1 gorny adres pierwszego bajtu do wyslania
> ; R2 ustala ilosc bajtow do wyslania
> ; R3 ustala ilosc rotacji bajtu przez carry
>
>
> TL0_DEF equ 03AH ; 0CBH dla 4MHz
> TH0_DEF equ 0FAH ; 0FAH bez zmian
>
> mov 028H,#000H ; end
> mov 029H,#000H
> mov 02AH,#002H
> mov 02BH,#0FAH
> mov 02CH,#05DH
> mov 02DH,#04BH
> mov 02EH,#0C9H
> mov 02FH,#059H ; SCEE
> mov 030H,#000H
> mov 031H,#000H
> mov 032H,#002H
> mov 033H,#0DAH
> mov 034H,#05DH
> mov 035H,#04BH
> mov 036H,#0C9H
> mov 037H,#059H ; SCEE
> mov 038H,#000H
> mov 039H,#000H
> mov 03AH,#002H
> mov 03BH,#0EAH
> mov 03CH,#05DH
> mov 03DH,#04BH
> mov 03EH,#0C9H
> mov 03FH,#059H ; SCEE
>
> mov R1,#03FH ; gorny adres pierwszego bajtu do nadania
> mov R2,#018H ; 22 bajty + 1
> mov R3,#008H ; ilosc rotacji + 1
> mov TH0,#000H ;niby koryguje pierwsze 4 ms
> mov TL0,#001H
> mov TCON,#00010000B ;start T0
>
> ALA: mov A,R2
> jnz ALA
> cpl LED
> mov TCON,#00000000B ; stop timera T0
> clr DANE
> mov R2,#018H ; ustawiam 22 bajty do wyslania
> mov R1,#03FH ; adres pierwszego bajtu do wyslania
> mov TH0,#TH0_DEF
> mov TL0,#TL0_DEF
> mov TCON,#00010000B ;start T0
> ljmp ALA
>
>
> PUNKT_1_SRV:
> push ACC
> push PSW
> mov TH0,#TH0_DEF ; timer na 4ms
> mov TL0,#TL0_DEF ; jw.
> djnz R3,rotate ;odejmij 1 i jump if not 0
> mov A,_at_nospam_R1 ;koncowka bajtu aby nie opuszczal 4ms
> mov C,ACC.0
> rrc A
> mov DANE,C
> mov _at_nospam_R1,A
> mov R3,#008H ;przygotowac nowa rotacje ustaw R1 do liczenia od pocz.
> dec R1
> dec R2
> pop PSW
> pop ACC
> reti
>
> rotate: mov A,_at_nospam_R1 ; zaladuj bajt danych do akumulatora
> mov C,ACC.0 ;korygowanie nieustalonego bitu carry !!!
> rrc A ; przekrec go przez carry
> mov DANE,C ;wyslij bit
> mov _at_nospam_R1,A ; zapisz przekrecony w jego miejsce
> pop PSW
> pop ACC
> reti
>
> end
>



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 12:28:02 GMT



NameNo napisał(a) w wiadomości: ...
A myślałem że Juliusz nie zajmuje się Hackiem. Tu projekty na FPGA a tu
takie małe na boku.

Dla sportu robi sie wiele rzeczy:-) Mam tez firmware nagrywarki takiej AUDIO
co lykala tylko plyty audio, a nie chciala czystych, komputerowych CDR :-)
PHILIPS. Tyle, ze musialem disassemblowac i poprawiac w HEX-ie. Strasznie
podla robota.

NameNo
P.S. Nie bądź taki pewny.


Hehe :-) Zobacz na date :-)
Szkoda, ze PIC-a nie ruszylem nigdy.

Juliusz


Poprzedni Następny
Wiadomoœć
spis treści
From: Romuald Bialy <romekb_at_nospam_polbox.com>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 17:09:58 GMT


Juliusz napisał(a):

A zreszta macie lamerio - cieszcie sie. To do modelu 7502 na 1051 :-) I tak
lamki nie macie programatorow to g.... wam z tego przyjdzie. A na dodatek
jak nie znacie assemblera to nie dojdziecie, ktory pin gdzie podlaczyc :-)

Juliusz
----------------------------------------------------------------------------
-----------------

; PSX
; Autor Juliusz Model 7502 ma zegar 4,43
NAME SONY_PLAY_STATION_REV_1051 final2


Poczepiam sie troche, taka juz moja natura... Nie zlosc sie zbytnio
!!!


[....]

;SCON_SetUp equ 11110000B
; |||||||^ - znacznik odebrania znaku RI
; ||||||^ - znacznik zakonczenia wysylania znaku TI
; |||||^ - dziewiaty znak odbierany RB8
; ||||^ - dziewiaty znak wysylany TB8
; |||^ - uaktywnienie odbiornika REN
; ||^ - multiproces
; |^ - tryb 3 seriala
; ^ - tryb 3 seriala
; mov SCON,#SCON_SetUp

Myslalem ze 1051 nie ma UARTA i w zwiazku z tym SCON'a... ale moze sie
myle ???
Nie istotne, i tak zbedna operacja.

[....]

;5) generowac oszukancze kody 12 bajtow

Hmmm, tu mamy 12 bajtow...

[....]

mov 028H,#000H ; end
mov 029H,#000H
mov 02AH,#002H
mov 02BH,#0FAH
mov 02CH,#05DH
mov 02DH,#04BH
mov 02EH,#0C9H
mov 02FH,#059H ; SCEE
mov 030H,#000H
mov 031H,#000H
mov 032H,#002H
mov 033H,#0DAH
mov 034H,#05DH
mov 035H,#04BH
mov 036H,#0C9H
mov 037H,#059H ; SCEE
mov 038H,#000H
mov 039H,#000H
mov 03AH,#002H
mov 03BH,#0EAH
mov 03CH,#05DH
mov 03DH,#04BH
mov 03EH,#0C9H
mov 03FH,#059H ; SCEE

Tu 24 bajty...

mov R1,#03FH ; gorny adres pierwszego bajtu do nadania
mov R2,#018H ; 22 bajty + 1

A tu 18H to 24 a nie 22.... Pelny brak konsekwencji. Ale dobrze, ma
byc 24 bajty.

[....]

clr DANE
mov R2,#018H ; ustawiam 22 bajty do wyslania

J.W.

[....]

Nieco skomplikowane i zagmatwane. Ja napisalbym to tak:

;=====================================================

;PROGRAM PLAYSTATION, AT89CX051, KWARC 4.43MHz

;PINY
LED EQU P1.4
DANE EQU P3.1
BLOK EQU P3.4
CON_1 EQU P3.7

;STALE
TH0_D EQU 0FAH
TL0_D EQU 03AH ;SZYBKOSC TRANSMISJI

;=====================================================
ORG 0 ;RESET
SJMP INIT
;-----------------------------------------------------
;POCZATEK PRZERWANIA

ORG 0BH ;TRANSMISJA W PRZERWANIU Z T0

PUSH PSW ;NA WSZELKI WYPADEK
MOV TH0,#TH0_D ;ZALADOWANIE TIMERA
MOV TL0,#TL0_D
RRC A ;W ACC BAJT DO WYSLANIA
MOV DANE,C ;WYSLANIE BITU NA PORT
DJNZ R2,EXIT ;LICZNIK BITOW

;LICZNIK BITOW DOSZEDL DO ZERA
INC DPTR ;ADRES NASTEPNEGO
CLR A
MOVC A,_at_nospam_A+DPTR ;POBRANIE KOLEJNEGO BAJTU Z TABLICY
MOV R2,#8 ;REINICJALIZACJA LICZNIKA BITOW
DJNZ R3,EXIT ;LICZNIK BAJTOW

;LICZNIK BAJTOW DOSZEDL DO ZERA
MOV R3,#24 ;REINICJALIZACJA LICZNIKA BAJTOW
MOV DPTR,#KODY ;ZACZNIJ OD POCZATKU TABLICY
CLR A
MOVC A,_at_nospam_A+DPTR ;POBRANIE PIERWSZY BAJT Z TABLICY
CPL LED ;MIGAJ LED'EM

EXIT: POP PSW
RETI

;KONIEC PRZERWANIA

;-----------------------------------------------------
;INICJALIZACJA

INIT: MOV PSW,#0 ;ZEROWANIE FLAG
MOV IE,#00000010B ;PRZERWANIE Z T0
MOV IP,A
MOV TCON,A ;T0 - STOP
MOV TMOD,#00010001B ;T0,T1 - 16 BIT TIMER
MOV TH0,#TH0_D
MOV TL0,#TL0_D
MOV R2,#8 ;8 BITOW
MOV R3,#24 ;24 BAJTY
MOV DPTR,#KODY ;ADRES TABLICY
CLR A
MOVC A,_at_nospam_A+DPTR ;POBIERZ PIERWSZY BAJT
CLR LED
CLR CON_1
CLR BLOK
CLR DANE ;USTAWIENIE PINOW
SETB EA ;WLACZENIE PRZERWAN
MOV TCON,#00010000B ;START T0
SPIJ: SJMP SPIJ ;NIE ROB NIC... PRZERWANIE ZROBI TO ZA CIEBIE :)))

DANE: DB 059H,0C9H,04BH,05DH,0EAH,002H,000H,000H
DB 059H,0C9H,04BH,05DH,0DAH,002H,000H,000H
DB 059H,0C9H,04BH,05DH,0FAH,002H,000H,000H


END

;==============================================================================

Latwo, krotko i przyjemnie !!
Algorytmy i dane wedlug programu Juliusza.


PS. Juliuszu, nie wrzucaj wszystkich do jednego worka z napisem
"LAMERZY" i nie udowadniaj swojej wyzszosci nad cala reszta.


--
Pozdrawiam.... Romuald Bialy
E'mail: romekb_at_nospam_polbox.com
WWW: http://www.polbox.com/r/romekb


Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 18:37:00 GMT


Poczepiam sie troche, taka juz moja natura... Nie zlosc sie zbytnio
Myslalem ze 1051 nie ma UARTA i w zwiazku z tym SCON'a... ale moze sie
myle ???
Nie istotne, i tak zbedna operacja.


Widzisz chyba, ze te linijki maja srednik :-)
Jak cos piszesz na szybkiego to tez kopiujesz naglowki z poprzednich
programow.

;5) generowac oszukancze kody 12 bajtow

Hmmm, tu mamy 12 bajtow...


No mamy 12, bo jak siedzialem z analizatorem stanow logicznych to pisalem
sibie teksty, a pozniej wyszlo inaczej :-) Tych bajtow moze byc znacznie
mniej ale nie chcialo mi sie tego poprawiac.

Tu 24 bajty...
Nieco skomplikowane i zagmatwane. Ja napisalbym to tak:


Trzeba bylo to samemu napisac :-) dwa lata temu :-) Wazne, ze dziala.


Latwo, krotko i przyjemnie !!

Moze i przyjemnie, ale tez dziala. Tam bylo ze 20 zmian wiec teksty zostaly
ze startch czasow i ilosci bajtow tez.


PS. Juliuszu, nie wrzucaj wszystkich do jednego worka z napisem
"LAMERZY" i nie udowadniaj swojej wyzszosci nad cala reszta.


Lamerzy to ci co stale pytaja o to samo, nie mogac sobie znalezc samemu w
sieci.

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: "GamBit" <gambit_at_nospam_promail.pl>
Subject: Odp: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 22:07:49 +0200



Lamerzy to ci co stale pytaja o to samo, nie mogac sobie znalezc samemu w
sieci.

No jak dla ciebie...zapytanie o cene jest lamerstwem ...to jestes wogole
niezly:))))





Poprzedni Następny
Wiadomoœć
spis treści
From: Romuald Bialy <romekb_at_nospam_polbox.com>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Tue, 17 Aug 1999 18:55:01 GMT


Juliusz napisał(a):

Widzisz chyba, ze te linijki maja srednik :-)
Jak cos piszesz na szybkiego to tez kopiujesz naglowki z poprzednich
programow.
A zgadza sie... nie lubie kopac po opisach SFR'ow, a wszystkich nie
pamietam (no bo po co ??) :). Co do srednikow to fakt,
niezauwazylem... sorki !

Trzeba bylo to samemu napisac :-) dwa lata temu :-) Wazne, ze dziala.

A tak, dziala, to sie liczy. Moze ciut zagmatwane, ale dziala !
A tak na marginesie to nie przerobilem jeszcze zadnego sonka, nie bawi
mnie to..., dlatego tez nigdy nie probowalem sie w to wgryzac. Mam
inne zajecia.

Lamerzy to ci co stale pytaja o to samo, nie mogac sobie znalezc samemu w
sieci.

Juliusz

No dobra, niech Ci bedzie... nie bedziemy sie przeciez sprzeczac !

--
Pozdrawiam.... Romuald Bialy
E'mail: romekb_at_nospam_polbox.com
WWW: http://www.polbox.com/r/romekb



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 18:59:43 GMT



Romuald Bialy napisał(a) w wiadomości: <37B84561.FD8AE7EB_at_nospam_polbox.com>...

Poczepiam sie troche, taka juz moja natura... Nie zlosc sie zbytnio


Gadac jest latwo jak sie widzi kod - ale moze nam wyjasnisz czemu takie
wlasnie bajty, a nie inne sa transmitowane i czemu akurat tak ? I co tam
wlasciwie leci ?

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: "Andy" <anok_at_nospam_ceti.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 22:46:14 +0200



Gadac jest latwo jak sie widzi kod - ale moze nam wyjasnisz czemu takie
wlasnie bajty, a nie inne sa transmitowane i czemu akurat tak ? I co tam
wlasciwie leci ?
Juliusz

Ty Juliusz jestes madry czlowiek.
Ja do dzis nie wiem co tam leci i jakie to ma znaczenia.

Jakis czas temu dostalem taka konsole przerobiona
i podlaczylem do niej analizator.

Potem na kontrolerze odtworzylem przebieg czasowy i poszlo.
Nie wiem czy we wszystkich jest tak samo bo dalej bawil sie z tym kumpel.

Moze mnie oswiecisz co to tam wlasciwie lata bo strasznie mnie to gryzie.

pzdr
Andrzej
anok_at_nospam_ceti.com.pl
anok_at_nospam_lupus.elektro.agh.edu.pl
KRAKOW



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 23:20:45 GMT



Andy napisał(a) w wiadomości: <7p9tam$84o$2_at_nospam_druid.ceti.com.pl>...
Ty Juliusz jestes madry czlowiek.

Bardzo mi milo :-)

Ja do dzis nie wiem co tam leci i jakie to ma znaczenia.


Juz mowie...

Dane sa podawane asynchronicznie z predkoscia okolo 250 baud i przerwa
kilkadziesiad ms miedzy nimi.
Chipy uniwersalne nadawaly naprzemiennie 3 kody stref tak, ze nie trzeba
bylo sie martwic gdzie zostal chip kupiony. Pozniej okazalo sie, ze jednak
kody innych krajow cos psuja (Zmieniki soft tego malego mikrokontrolere
chyba) lub w niektorych modelach tylko.

Wiec tak

Serial ma odwrocona polaryzacje dla zmylki. Odwroc sobie i porownaj z tabela
ASCII. 1 start bit i 2 stop bity

00 10111110 1 00 10111010 1 00 10111100 1 00 10101100 1 <=AECS (od
prawej)
00 10111010 1 00 10111010 1 00 10111100 1 00 10101100 1 <=EECS (od
prawej)
00 10110110 1 00 10111010 1 00 10111100 1 00 10101100 1 <=IECS (od
prawej)

jak przegrupujesz to w oktety dla potrzeb emulowanego seriala przy pomocy
przerwania to wychodzi

00000010 11111010 01011101 01001011 11001001 01011001
00000010 11101010 01011101 01001011 11001001 01011001
00000010 11011010 01011101 01001011 11001001 01011001

gdzie koncowki dopelniasz zerami (jakby wydluzenie stop bitow)

a dalej zamieniasz na HEX i po sprawie. Wystarczy transmitowac odpowiednio
jedna z sekwencji.


02 EA 5D 4B C9 59 SCEE
... pozostale tak samo

Teraz nie pamietam czy LSB czy MSB bit idzie na poczatek ale popatrz w kod
to zobaczysz.

To cale tajemnicze zabezpieczenie :-) Na plytach jest sektor z taka
sekwencja, ktorego nie kopiuja CDR-y a na oryginalach jest oczywiscie inny.
Z historii wynika, ze ktos kiedys przypadkiem stwierdzil, ze przegrana plyta
chodzi tak samo jak importowana z innego reginu. I tak to sie zaczelo.

Jest to chamskie sypanie kilkoma bajtami, ktore znacza dokladnie SCEE, SCEA
lub SCEI i zapisane w odpowiedniej formie. Sygnal ten przechodzi przez
wzmacniacz operacyjny, ktory stanowi jakby bufor pomiedzy logika 3.5V i 5V.
Jedna z nozek scalaka normalnie blokujesz to pociagajac wejscie do masy. A
za nim wpuszczasz wlasciwy sygnal. Dalej sygnal leci do mikrokontrolera OTP
czy programowanego maska, ktory steruje kontrolerem CD-ROMu i komunikuje sie
z ROM-em konsolki. Mozna to ominac bez chipa zadnego, ale wymaga to ciecia
kilku sciezek, laczenia drutem i jest malo eleganckie.

Ten chip co ja mialem w lecie 2 lata temu mial kilkanascie kabelkow i
dzialal pod warunkiem pojawienia sie kilku dodatkowych stanow logicznych na
PCB - dla zmylki oczywiscie, zeby sie ludzie zastanawiali :-) Jak widac nie
jest to takie oczywiste - zrobic cos takiego i gadajace glowy moga mnie
poprawiac :-) Ha ciekawe co oni zrobili :-) Moze hackneli czyjs programator
eepromow podlaczany do portu drukarki ? :-)

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: "Andy" <anok_at_nospam_ceti.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Tue, 17 Aug 1999 03:41:42 +0200


Juliusz napisał(a) w wiadomości: ...


...
Dane sa podawane asynchronicznie z predkoscia okolo 250 baud i przerwa
kilkadziesiad ms miedzy nimi.
Chipy uniwersalne nadawaly naprzemiennie 3 kody stref tak, ze nie trzeba
bylo sie martwic gdzie zostal chip kupiony. Pozniej okazalo sie, ze jednak
kody innych krajow cos psuja (Zmieniki soft tego malego mikrokontrolere
chyba) lub w niektorych modelach tylko.


Transmisje z takim wlasnie Chip'em analizowalem bo pamietam,
ze lecialy trzy rozne paczki z pewnymi przerwami miedzy nimi.


To cale tajemnicze zabezpieczenie :-) Na plytach jest sektor z taka
sekwencja, ktorego nie kopiuja CDR-y a na oryginalach jest oczywiscie inny.
Z historii wynika, ze ktos kiedys przypadkiem stwierdzil, ze przegrana
plyta
chodzi tak samo jak importowana z innego reginu. I tak to sie zaczelo.
...

Tego sie domyslalem.

dzieki
--
Andrzej
anok_at_nospam_ceti.com.pl
anok_at_nospam_lupus.elektro.agh.edu.pl
KRAKOW



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Tue, 17 Aug 1999 11:28:23 GMT



Andy napisał(a) w wiadomości: <7paejf$caq$1_at_nospam_druid.ceti.com.pl>...
Transmisje z takim wlasnie Chip'em analizowalem bo pamietam,
ze lecialy trzy rozne paczki z pewnymi przerwami miedzy nimi.


He, ale wyobraz sobie, ze jakby ktos to zrobil tylko w celu ominiecia
regionow. Przykladowo na PLD. Mozna powiedzmy "poprawiac" w locie 1 czy 2
bity, ktore lecialy tymi sciezkami z oryginalnej plyty. Piraty by nie
dzialaly, ale oryginaly z innej strefy tak.

Ciekawi mnie tylko kto to pierwszy na swiecie wymyslil. Czy to wycieklo z
dokumentacji sony, jakiejs produkcyjnej, tajnej, czy byl genialny facet co
siedzial z cyfrowym oscyloskopem i badal kolejno po sciezkach. W koncu to
sygnaly subcode tylko ale zawsze :-)

Zreszta wlasciwie jesli sie ma analizator z duza pamiecia to widac wszystko
i porownywac mozna do woli.

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: "Andy" <anok_at_nospam_ceti.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Tue, 17 Aug 1999 23:56:55 +0200


Juliusz napisał(a) w wiadomości: ...
...
Ciekawi mnie tylko kto to pierwszy na swiecie wymyslil. Czy to wycieklo z
dokumentacji sony, jakiejs produkcyjnej, tajnej, czy byl genialny facet co
siedzial z cyfrowym oscyloskopem i badal kolejno po sciezkach. W koncu to
sygnaly subcode tylko ale zawsze :-)



Jesli ten, ktory to zrobil pierwszy sam to wymyslil to byl niezly
bo zrobic to jesli sie ma dokumentacje to juz nie sztuka.

pzdr
--
Andrzej
anok_at_nospam_ceti.com.pl
anok_at_nospam_lupus.elektro.agh.edu.pl
KRAKOW



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Wed, 18 Aug 1999 00:57:07 GMT



Andy napisał(a) w wiadomości: <7pclq2$s2t$1_at_nospam_druid.ceti.com.pl>...
Jesli ten, ktory to zrobil pierwszy sam to wymyslil to byl niezly
bo zrobic to jesli sie ma dokumentacje to juz nie sztuka.


Wlasnie ! Ale do tych scalakow, co tam siedza, to nawet teraz nie dostaniesz
PDF-a. Wiec nie sadze, ze macal po wszystkim. Musial miec maly cynk. No
chyba, ze macal faktycznie. Zreszta jak masz analizator stanow to dotykasz
po kolei i zaczytujesz co leci. W koncu ten maly mikrokontroler dawal wiele
do myslenia - po jakiego diabla on tam siedzi.

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: "Marek Lewandowski" <twilight_at_nospam_callisto.krakow.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Wed, 18 Aug 1999 22:22:31 +0200


Jeżeli mój... dokładniej mojego ojca znajomy potrafi rozkumać i połamać
zabezpieczenia np. LEX-a w ciągu kilku godzin, to może był taki orzeł i
rzeczywiście zgadł?
Albo - myślę - mógł ktoś kupić dwa PSy z różnych regionów i porównywać
przebiegi.

--
Marek Lewandowski
mailto:twilight_at_nospam_callisto.krakow.pl ICQ#: 10139051
mailto:twilight_at_nospam_gdynia.multinet.pl
Student _at_nospam_ Technical University of Gdansk, Poland
http://www.callisto.krakow.pl/~twilight



Juliusz napisał(a) w wiadomości: ...
>
>Andy napisał(a) w wiadomości: <7pclq2$s2t$1_at_nospam_druid.ceti.com.pl>...
>>Jesli ten, ktory to zrobil pierwszy sam to wymyslil to byl niezly
>>bo zrobic to jesli sie ma dokumentacje to juz nie sztuka.
>
>
>Wlasnie ! Ale do tych scalakow, co tam siedza, to nawet teraz nie
dostaniesz
>PDF-a. Wiec nie sadze, ze macal po wszystkim. Musial miec maly cynk. No
>chyba, ze macal faktycznie. Zreszta jak masz analizator stanow to dotykasz
>po kolei i zaczytujesz co leci. W koncu ten maly mikrokontroler dawal wiele
>do myslenia - po jakiego diabla on tam siedzi.
>
>Juliusz
>
>



Poprzedni Następny
Wiadomoœć
spis treści
From: Romuald Bialy <romekb_at_nospam_polbox.com>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Tue, 17 Aug 1999 18:55:05 GMT


Juliusz napisał(a):

Romuald Bialy napisał(a) w wiadomości: <37B84561.FD8AE7EB_at_nospam_polbox.com>...

Poczepiam sie troche, taka juz moja natura... Nie zlosc sie zbytnio

Gadac jest latwo jak sie widzi kod - ale moze nam wyjasnisz czemu takie
wlasnie bajty, a nie inne sa transmitowane i czemu akurat tak ? I co tam
wlasciwie leci ?

Juliusz

O wielki Juliuszu, tys przylozyl analizator gdzie trzeba, mnie sie po
prostu nie chcialo :))))
Jak mowilem wczesniej playstation sie nie interesowalem wiec nie
odpowiem czemu takie a nie inne...

--
Pozdrawiam.... Romuald Bialy
E'mail: romekb_at_nospam_polbox.com
WWW: http://www.polbox.com/r/romekb



Poprzedni Następny
Wiadomoœć
spis treści
From: "Juliusz" <juliusz_at_nospam_multi-ip.com.pl>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Mon, 16 Aug 1999 19:01:02 GMT


A teraz odpowiem na pytanie "po ile chodza chipy do przrobki Playstation?" -
po tyle ile sa czyste procesory :-)

Juliusz



Poprzedni Następny
Wiadomoœć
spis treści
From: Romuald Bialy <romekb_at_nospam_polbox.com>
Subject: Re: po ile chodza chipy do przrobki Playstation
Date: Tue, 17 Aug 1999 18:55:06 GMT



Juliusz napisał(a):

A teraz odpowiem na pytanie "po ile chodza chipy do przrobki Playstation?" -
po tyle ile sa czyste procesory :-)

Juliusz

plus 0,001 kWh x cena energii (na zaprogramowanie) :-)))

--
Pozdrawiam.... Romuald Bialy
E'mail: romekb_at_nospam_polbox.com
WWW: http://www.polbox.com/r/romekb